Protected Sub convertToPdfButton_Click(ByVal sender As Object, ByVal e As EventArgs)
    ' Create a HTML to PDF converter object with default settings
    Dim htmlToPdfConverter As New HtmlToPdfConverter()

    ' Set license key received after purchase to use the converter in licensed mode
    ' Leave it not set to use the converter in demo mode
    htmlToPdfConverter.LicenseKey = "fvDh8eDx4fHg4P/h8eLg/+Dj/+jo6Og="

    ' Set an adddional delay in seconds to wait for JavaScript or AJAX calls after page load completed
    ' Set this property to 0 if you don't need to wait for such asynchcronous operations to finish
    htmlToPdfConverter.ConversionDelay = 2

    Dim pdfDocument As Document = Nothing
    Try
        ' Convert a HTML page to a PDF document object
        pdfDocument = htmlToPdfConverter.ConvertUrlToPdfDocumentObject(urlTextBox.Text)

        Dim goToPageNumber As Integer = Integer.Parse(pageNumberTextBox.Text)
        If goToPageNumber > pdfDocument.Pages.Count Then
            Return
        End If

        ' Get destination PDF page
        Dim goToPage As PdfPage = pdfDocument.Pages(goToPageNumber - 1)

        ' Get the destination point in PDF page
        Dim goToX As Single = Single.Parse(xLocationTextBox.Text)
        Dim goToY As Single = Single.Parse(yLocationTextBox.Text)

        Dim goToLocation As New PointF(goToX, goToY)

        ' Get the destination view mode
        Dim viewMode As DestinationViewMode = SelectedViewMode()

        ' Create the destination in PDF document
        Dim goToDestination As New ExplicitDestination(goToPage, goToLocation, viewMode)

        ' Set the zoom level when the destination is displayed
        If viewMode = DestinationViewMode.XYZ Then
            goToDestination.ZoomPercentage = Integer.Parse(zoomLevelTextBox.Text)
        End If

        ' Set the document Go To open action
        pdfDocument.OpenAction.Action = New PdfActionGoTo(goToDestination)

        ' Save the PDF document in a memory buffer
        Dim outPdfBuffer() As Byte = pdfDocument.Save()

        ' Send the PDF as response to browser

        ' Set response content type
        Response.AddHeader("Content-Type", "application/pdf")

        ' Instruct the browser to open the PDF file as an attachment or inline
        Response.AddHeader("Content-Disposition", String.Format("attachment; filename=Set_Initial_Zoom_Level.pdf; size={0}", outPdfBuffer.Length.ToString()))

        ' Write the PDF document buffer to HTTP response
        Response.BinaryWrite(outPdfBuffer)

        ' End the HTTP response and stop the current page processing
        Response.End()
    Finally
        ' Close the PDF document
        If pdfDocument IsNot Nothing Then
            pdfDocument.Close()
        End If
    End Try
End Sub